Select pour récupérer le SIRET

[Eric_C]

Bonjour à tous,

Je découvre GraphQL et la base Datatourisme. L’outil est super mais je peine encore à extraire la donnée

Si quelqu’un peut m’aider à débugger ma requête svp ?
J’ai essayé de m’aider d’autres topics en vain

Select ?nom ?org ?siret ?longitude ?latitude ?capacite ?Hours ?Audience WHERE {
?poi a :Accommodation; ## est un hébergement
:isLocatedAt ?place; ## qui est localisé à ?place
rdfs:label ?nom; ## et a pour nom ?nom.
:hasAudience ?Audience;
:isOwnedBy ?org;

   FILTER langMatches( lang(?nom), "fr" )   ## en français  

?place schema:geo ?geo. ## ?place a pour coordonnées géographiques ?geo
?geo schema:longitude ?longitude; ## ?geo a pour longitude ?longitude
schema:latitude ?latitude. ## et a pour latitude ?latitude
?place schema:openingHoursSpecification ?Hours.
?org :siret ?siret.

optional {?poi :allowedPersons ?capacite.
} ## qui peut avoir l’information de capacité d’accueil ?capacite
}

Merci et très belle journée !

[conjecto]

Bonjour,

Votre requête SPARQL est bonne mais il n’y a que 785 POI Hébergement dont le propriétaire a un n° Siret dans la base actuellement.
Hors aucun de ces 785 POI n’a de d’horaire d’ouverture spécifié.

Voici votre requête avec les horaires, les siret et les audiences (qui sont assé rarement renseignées à ce jour) en optional.

PREFIX : <https://www.datatourisme.gouv.fr/ontology/core#> 
PREFIX schema: <http://schema.org/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

Select ?nom ?org ?siret ?longitude ?latitude ?capacite ?Hours ?Audience WHERE {
  ?poi a :Accommodation; ## est un hébergement
  :isLocatedAt ?place; ## qui est localisé à ?place
  rdfs:label ?nom; ## et a pour nom ?nom
  :isOwnedBy ?org.

  FILTER langMatches( lang(?nom), "fr" )   ## en français  

  ?place schema:geo ?geo. ## ?place a pour coordonnées géographiques ?geo
  ?geo schema:longitude ?longitude; ## ?geo a pour longitude ?longitude
  schema:latitude ?latitude. ## et a pour latitude ?latitude

  optional {?poi   :hasAudience ?Audience.}
  optional {?place schema:openingHoursSpecification ?Hours.}
  optional {?org :siret ?siret.}
  
  optional {?poi :allowedPersons ?capacite.} ## qui peut avoir l’information de capacité d’accueil ?capacite
}

Cordialement.